# Copyright (c) 2005-2007 Andre Merzky (andre@merzky.net)
# Copyright (c)      2008 Ole Weidner (oweidner@cct.lsu.ed)
# 
# Distributed under the Boost Software License, Version 1.0. 
# (See accompanying Afile LICENSE_1_0.txt or copy at 
#  http://www.boost.org/LICENSE_1_0.txt)

# find saga.m4

m4_include([saga.m4])
m4_include([saga_glite_cream.m4])
m4_include([saga_ldap.m4])
m4_include([saga_xerces.m4])

AC_INIT()

AX_SAGA_CONFIG()

AC_ARG_ENABLE([adaptor-cream-job],
              [AS_HELP_STRING([--enable-adaptor-cream-job],
                              [build cream job adaptor
                               (default: enabled)])],
              [],
              [enable_adaptor_cream_job=yes])

AC_ARG_ENABLE([adaptor-glite-sd],
              [AS_HELP_STRING([--enable-adaptor-glite-sd],
                              [build glite service discovery adaptor
                               (default: enabled)])],
              [],
              [enable_adaptor_glite_sd=yes])

AC_ARG_ENABLE([adaptor-glite-isn],
              [AS_HELP_STRING([--enable-adaptor-glite-isn],
                              [build glite information service navigator adaptor 
                               (default: enabled)])],
              [],
              [enable_adaptor_glite_isn=yes])

AX_SAGA_CHECK_GLITE()
AX_SAGA_CHECK_LDAP()
AX_SAGA_CHECK_XERCESC()

SAGA_DEP_FILES="$SAGA_LOCATION/include/saga/saga.hpp"
SAGA_DEP_FILES="$SAGA_DEP_FILES $SAGA_GLITE_DEP_FILES"
SAGA_DEP_FILES="$SAGA_DEP_FILES $SAGA_LDAP_DEP_FILES"
SAGA_DEP_FILES="$SAGA_DEP_FILES $SAGA_XERCESC_DEP_FILES"

# create output files
AC_CONFIG_FILES([config/make.cfg])

# debian and redhat package support
AX_SAGA_CHECK_DEBDEPS([$SAGA_DEP_FILES])
AX_SAGA_CHECK_RPMDEPS([$SAGA_DEP_FILES])

SAGA_CONFIGURE_OK=yes
if ! test "$HAVE_SAGA" = "yes"; then SAGA_CONFIGURE_OK=no; fi
AC_SUBST([SAGA_CONFIGURE_OK])

BUILD_ADAPTOR_JOB="no"
BUILD_ADAPTOR_SD="no"
BUILD_ADAPTOR_ISN="no"

if test "$enable_adaptor_cream_job-$SAGA_HAVE_PACKAGE_JOB-$SAGA_HAVE_GLITE" = "yes-yes-yes"; then
  BUILD_ADAPTOR_JOB="yes"
fi

if test "$enable_adaptor_glite_sd-$SAGA_HAVE_PACKAGE_SD-$SAGA_HAVE_LDAP" = "yes-yes-yes"; then
  BUILD_ADAPTOR_SD="yes"
fi

if test "$enable_adaptor_glite_isn-$SAGA_HAVE_PACKAGE_ISN-$SAGA_HAVE_LDAP-$SAGA_HAVE_XERCESC" = "yes-yes-yes-yes"; then
  BUILD_ADAPTOR_ISN="yes"
fi

AC_SUBST([BUILD_ADAPTOR_JOB])
AC_SUBST([BUILD_ADAPTOR_SD])
AC_SUBST([BUILD_ADAPTOR_ISN])

AC_OUTPUT()


OUT=config.summary
rm -f $OUT
touch $OUT

echo "                                                                 " >> $OUT
echo " ========================================================        " >> $OUT
echo " SAGA GLITE CREAM ADAPTOR - Configuration Summary                " >> $OUT
echo " ========================================================        " >> $OUT
echo "                                                                 " >> $OUT
echo " Using SAGA from       : $SAGA_LOCATION                          " >> $OUT
echo "       SAGA version    : $SAGA_VERSION                           " >> $OUT
echo "                                                                 " >> $OUT
echo " Adaptor Version       : $SAGA_PACKAGE_VERSION                   " >> $OUT
echo " Adaptor Revision      : $SAGA_PACKAGE_REVISION                  " >> $OUT
echo "                                                                 " >> $OUT
echo " gLite Found           : $SAGA_HAVE_GLITE                        " >> $OUT
echo " gLite Version         : $GLITE_VERSION                          " >> $OUT
echo " gLite Location        : $GLITE_LOCATION                         " >> $OUT
echo " gLite Config          : $GLITE_CONFIG                           " >> $OUT
echo " gLite Path            : $GLITE_PATH                             " >> $OUT
echo "                                                                 " >> $OUT
echo " Xerces-C Found        : $SAGA_HAVE_XERCESC                      " >> $OUT
echo " Xerces-C Version      : $XERCESC_VERSION                        " >> $OUT
echo " Xerces-C Location     : $XERCESC_LOCATION                       " >> $OUT
echo "                                                                 " >> $OUT
echo " LDAP Found            : $SAGA_HAVE_LDAP                         " >> $OUT
echo " LDAP Version          : $LDAP_VERSION                           " >> $OUT
echo " LDAP Location         : $LDAP_LOCATION                          " >> $OUT
echo "                                                                 " >> $OUT
echo " Job Adaptor           : $BUILD_ADAPTOR_JOB                      " >> $OUT
echo " SD  Adaptor           : $BUILD_ADAPTOR_SD                       " >> $OUT
echo " ISN Adaptor           : $BUILD_ADAPTOR_ISN                      " >> $OUT
echo "                                                                 " >> $OUT
echo " ========================================================        " >> $OUT
echo "                                                                 " >> $OUT

cat $OUT