#include "cctk.h"
#include "cctk_Functions.h"
#include "cctk_Parameters.h"

subroutine deriv_gf_4_2 ( var, ni, nj, nk, dir, bb, gsize, delta, dvar )

  implicit none

  DECLARE_CCTK_FUNCTIONS
  DECLARE_CCTK_PARAMETERS

  CCTK_REAL, parameter :: zero = 0.0
  integer, parameter :: wp = kind(zero)
  CCTK_INT, intent(IN) :: ni, nj, nk
  CCTK_REAL, dimension(ni,nj,nk), intent(IN) :: var
  CCTK_INT, intent(IN) :: dir
  CCTK_INT, intent(IN) :: bb(2)
  CCTK_INT, intent(IN) :: gsize
  CCTK_REAL, intent(IN) :: delta
  CCTK_REAL, dimension(ni,nj,nk), intent(OUT) :: dvar

  CCTK_REAL, dimension(2), save :: a
  CCTK_REAL, dimension(6,4), save :: q 
  CCTK_REAL :: idel

  CCTK_INT :: il, ir, jl, jr, kl, kr

  logical, save :: first = .true.

  if ( first ) then
    a(1) = 2.0_wp/3.0_wp; a(2) = -1.0_wp/12.0_wp

    q(1,1) = -24.0_wp/17.0_wp; q(2,1) = 59.0_wp/34.0_wp
    q(3,1) = -4.0_wp/17.0_wp; q(4,1) = -3.0_wp/34.0_wp
    q(5,1) = zero; q(6,1) = zero
    q(1,2) = -1.0_wp/2.0_wp; q(2,2) = zero
    q(3,2) = 1.0_wp/2.0_wp; q(4,2) = zero
    q(5,2) = zero; q(6,2) = zero
    q(1,3) = 4.0_wp/43.0_wp; q(2,3) = -59.0_wp/86.0_wp
    q(3,3) = zero; q(4,3) = 59.0_wp/86.0_wp
    q(5,3) = -4.0_wp/43.0_wp; q(6,3) = zero
    q(1,4) = 3.0_wp/98.0_wp; q(2,4) = zero
    q(3,4) = -59.0_wp/98.0_wp; q(4,4) = zero
    q(5,4) = 32.0_wp/49.0_wp; q(6,4) = -4.0_wp/49.0_wp
    first = .false.
  end if

  idel = 1.0_wp / delta

  direction: select case (dir)
  case (0) direction
    if ( bb(1) == 0 ) then
      il = 1 + gsize
    else
      dvar(1,:,:) = ( q(1,1) * var(1,:,:) + q(2,1) * var(2,:,:)  + &
                      q(3,1) * var(3,:,:) + q(4,1) * var(4,:,:) ) * idel
      dvar(2,:,:) = ( q(1,2) * var(1,:,:) + q(3,2) * var(3,:,:) ) * idel
      dvar(3,:,:) = ( q(1,3) * var(1,:,:) + q(2,3) * var(2,:,:) + &
                      q(4,3) * var(4,:,:) + q(5,3) * var(5,:,:) ) * idel
      dvar(4,:,:) = ( q(1,4) * var(1,:,:) + q(3,4) * var(3,:,:) + &
                      q(5,4) * var(5,:,:) + q(6,4) * var(6,:,:) ) * idel
      il = 5
    end if
    if ( bb(2) == 0 ) then
      ir = ni - gsize
    else
      dvar(ni-3,:,:) = - ( q(1,4) * var(ni,:,:) + &
                           q(3,4) * var(ni-2,:,:) + &
                           q(5,4) * var(ni-4,:,:) + &
                           q(6,4) * var(ni-5,:,:) ) * idel
      dvar(ni-2,:,:) = - ( q(1,3) * var(ni,:,:) + &
                           q(2,3) * var(ni-1,:,:) + &
                           q(4,3) * var(ni-3,:,:) + &
                           q(5,3) * var(ni-4,:,:) ) * idel
      dvar(ni-1,:,:) = - ( q(1,2) * var(ni,:,:) + &
                           q(3,2) * var(ni-2,:,:) ) * idel
      dvar(ni,:,:)   = - ( q(1,1) * var(ni,:,:) + &
                           q(2,1) * var(ni-1,:,:) + &
                           q(3,1) * var(ni-2,:,:) + &
                           q(4,1) * var(ni-3,:,:) ) * idel
      ir = ni - 4
    end if
    dvar(il:ir,:,:) = ( a(1) * ( var(il+1:ir+1,:,:) - &
                                 var(il-1:ir-1,:,:) ) + &
                        a(2) * ( var(il+2:ir+2,:,:) - &
                                 var(il-2:ir-2,:,:) ) ) * idel
  case (1) direction
    if ( bb(1) == 0 ) then
      jl = 1 + gsize
    else
      dvar(:,1,:) = ( q(1,1) * var(:,1,:) + q(2,1) * var(:,2,:)  + &
                      q(3,1) * var(:,3,:) + q(4,1) * var(:,4,:) ) * idel
      dvar(:,2,:) = ( q(1,2) * var(:,1,:) + q(3,2) * var(:,3,:) ) * idel
      dvar(:,3,:) = ( q(1,3) * var(:,1,:) + q(2,3) * var(:,2,:) + &
                      q(4,3) * var(:,4,:) + q(5,3) * var(:,5,:) ) * idel
      dvar(:,4,:) = ( q(1,4) * var(:,1,:) + q(3,4) * var(:,3,:) + &
                      q(5,4) * var(:,5,:) + q(6,4) * var(:,6,:) ) * idel
      jl = 5
    end if
    if ( bb(2) == 0 ) then
      jr = nj - gsize
    else
      dvar(:,nj-3,:) = - ( q(1,4) * var(:,nj,:) + &
                           q(3,4) * var(:,nj-2,:) + &
                           q(5,4) * var(:,nj-4,:) + &
                           q(6,4) * var(:,nj-5,:) ) * idel
      dvar(:,nj-2,:) = - ( q(1,3) * var(:,nj,:) + &
                           q(2,3) * var(:,nj-1,:) + &
                           q(4,3) * var(:,nj-3,:) + &
                           q(5,3) * var(:,nj-4,:) ) * idel
      dvar(:,nj-1,:) = - ( q(1,2) * var(:,nj,:) + &
                           q(3,2) * var(:,nj-2,:) ) * idel
      dvar(:,nj,:)   = - ( q(1,1) * var(:,nj,:) + &
                           q(2,1) * var(:,nj-1,:) + &
                           q(3,1) * var(:,nj-2,:) + &
                           q(4,1) * var(:,nj-3,:) ) * idel
      jr = nj - 4
    end if
    dvar(:,jl:jr,:) = ( a(1) * ( var(:,jl+1:jr+1,:) - &
                                 var(:,jl-1:jr-1,:) ) + &
                        a(2) * ( var(:,jl+2:jr+2,:) - &
                                 var(:,jl-2:jr-2,:) ) ) * idel
  case (2) direction
    if ( bb(1) == 0 ) then
      kl = 1 + gsize
    else
      dvar(:,:,1) = ( q(1,1) * var(:,:,1) + q(2,1) * var(:,:,2)  + &
                      q(3,1) * var(:,:,3) + q(4,1) * var(:,:,4) ) * idel
      dvar(:,:,2) = ( q(1,2) * var(:,:,1) + q(3,2) * var(:,:,3) ) * idel
      dvar(:,:,3) = ( q(1,3) * var(:,:,1) + q(2,3) * var(:,:,2) + &
                      q(4,3) * var(:,:,4) + q(5,3) * var(:,:,5) ) * idel
      dvar(:,:,4) = ( q(1,4) * var(:,:,1) + q(3,4) * var(:,:,3) + &
                      q(5,4) * var(:,:,5) + q(6,4) * var(:,:,6) ) * idel
      kl = 5
    end if
    if ( bb(2) == 0 ) then
      kr = nk - gsize
    else 
      dvar(:,:,nk-3) = - ( q(1,4) * var(:,:,nk) + &
                           q(3,4) * var(:,:,nk-2) + &
                           q(5,4) * var(:,:,nk-4) + &
                           q(6,4) * var(:,:,nk-5) ) * idel
      dvar(:,:,nk-2) = - ( q(1,3) * var(:,:,nk) + &
                           q(2,3) * var(:,:,nk-1) + &
                           q(4,3) * var(:,:,nk-3) + &
                           q(5,3) * var(:,:,nk-4) ) * idel
      dvar(:,:,nk-1) = - ( q(1,2) * var(:,:,nk) + &
                           q(3,2) * var(:,:,nk-2) ) * idel
      dvar(:,:,nk)   = - ( q(1,1) * var(:,:,nk) + &
                           q(2,1) * var(:,:,nk-1) + &
                           q(3,1) * var(:,:,nk-2) + &
                           q(4,1) * var(:,:,nk-3) ) * idel
      kr = nk - 4
    end if
    dvar(:,:,kl:kr) = ( a(1) * ( var(:,:,kl+1:kr+1) - &
                                 var(:,:,kl-1:kr-1) ) + &
                        a(2) * ( var(:,:,kl+2:kr+2) - &
                                 var(:,:,kl-2:kr-2) ) ) * idel
  end select direction
end subroutine deriv_gf_4_2